Forum SAGA

Aici ne tutuim, vorbim, ne imprietenim
https://forum.sagasoft.ro/

Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

https://forum.sagasoft.ro/viewtopic.php?t=61130

Pagina 2 din 2

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Mar Aug 11, 2026 2:49 pm
de ciucam544
UPDATE: Pentru ca la fiecare actualizare de Adobe Acrobat se activeaza Protected Mode si Enhanced Security, aceste optiuni trebuie mereu dezactivate (pentru a putea vizualiza din saga PDF-urile generate).
Am refacut un scriptul, pentru a dezactiva aceaste optiuni si dupa actualizarile viitoare ale programului Adobe Acrobat.
Se ruleaza doar o singura data in windows si gata. In Adobe Acrobat sau in Acrobat Reader nu vor mai fi active sau bifate Enable Protected Mode at startup si Enable Enhanced Security.

DisableAdobeAcrobatPMES.cmd

Cod: Selectaţi tot

net session >nul 2>&1 || (powershell -NoProfile -Command "Start-Process -FilePath '%~f0' -Verb RunAs" & exit /b)
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Adobe\Acrobat Reader\DC\FeatureLockDown" /v "bProtectedMode" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Adobe\Acrobat Reader\DC\FeatureLockDown" /v "bEnhancedSecurityStandalone" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Adobe\Acrobat Reader\DC\FeatureLockDown" /v "bEnhancedSecurityInBrowser" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Policies\Adobe\Acrobat Reader\DC\FeatureLockDown" /v "bProtectedMode" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Policies\Adobe\Acrobat Reader\DC\FeatureLockDown" /v "bEnhancedSecurityStandalone" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Policies\Adobe\Acrobat Reader\DC\FeatureLockDown" /v "bEnhancedSecurityInBrowser" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Adobe\Adobe Acrobat\DC\FeatureLockDown" /v "bProtectedMode" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Adobe\Adobe Acrobat\DC\FeatureLockDown" /v "bEnhancedSecurityStandalone" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Adobe\Adobe Acrobat\DC\FeatureLockDown" /v "bEnhancedSecurityInBrowser" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Policies\Adobe\Adobe Acrobat\DC\FeatureLockDown" /v "bProtectedMode" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Policies\Adobe\Adobe Acrobat\DC\FeatureLockDown" /v "bEnhancedSecurityStandalone" /t REG_DWORD /d 0 /f
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Policies\Adobe\Adobe Acrobat\DC\FeatureLockDown" /v "bEnhancedSecurityInBrowser" /t REG_DWORD /d 0 /f
pause

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Lun Aug 17, 2026 12:44 pm
de iliovicid825
Multumesc ptr. script!
Apropo, nu există o alternativă decenta la acest nenorocit de Adobe Reader?

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Lun Aug 17, 2026 4:30 pm
de ciucam544
Din pacate nu. Adobe este singura companie care face softul ce poate rula corect scripturile si cripta corect semnaturile in tipizatele de la ANAF, probabil tocmai pt. ca sunt generate cu softul de la Adobe.

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Mar Sep 01, 2026 5:18 pm
de ciucam544
ActualizareSagaKitCompletSmart_V4.1.cmd

Cod: Selectaţi tot

@echo off
set cd=%~dp0
set cd=%cd:~0,-1%
net session >nul 2>&1 || (setx SagaCale "%cd%" >nul & powershell -NoProfile -Command "Start-Process -FilePath '%~f0' -Verb RunAs" & exit /b)
title - Actualizare Saga Kit Complet Smart V4.1 - 2026(c)byGabrieL
for /f "delims=" %%C in ('powershell -NoProfile -Command "(Get-Item Env:SagaCale).Value"') do set "CaleSaga=%%C"
if exist "%CaleSaga%\sb.exe" (set "SagaTip=SagaB" & set "SetupSaga=SetupB.exe" & set "CaleTipInit=Lite B 3" & set "Page=saga-b.php" & set "Link=SAGA B.3.0")
if exist "%CaleSaga%\sc.exe" (set "SagaTip=SagaC" & set "SetupSaga=SetupC.exe" & set "CaleTipInit=Lite C 3" & set "Page=saga-c.php" & set "Link=SAGA C.3.0")
if exist "%CaleSaga%\sps.exe" (set "SagaTip=SagaPS" & set "SetupSaga=SetupPS.exe" & set "CaleTipInit=PS 3" & set "Page=saga-ps.php" & set "Link=SAGA PS.3.0")
if "%SagaTip%"=="" (color 0c & echo Nu exista un program saga in folderul curent ! & pause & exit /b)
for /f %%T in ('powershell -NoProfile -Command "Get-Date -Format yyyy.MM.dd_HH.mm.ss"') do set "DATE=%%T"
for /f "usebackq delims=" %%V in (`powershell -NoProfile -Command "$h=Invoke-WebRequest 'https://www.sagasoft.ro/%Page%' -UseBasicParsing; if($h.Content -match 'Versiune:</b>\s*([0-9\.]+)') { $matches[1] }"`) do set "VER=%%V"
color 0a & echo Program Saga detectat: %SagaTip% - Versiune v%VER%.
set "Upd=%CaleSaga%\Actualizari"
if not exist "%Upd%" mkdir "%Upd%"
set "KitSaga=%Upd%\%SagaTip%_%DATE%_v%VER%.exe"
if exist "%Upd%\%SagaTip%_%DATE:~0,13%*_v%VER%.exe" (
for /f "delims=" %%F in ('dir /b /o:-d "%Upd%\%SagaTip%_%DATE:~0,13%*_v%VER%.exe"') do set "KitSaga=%Upd%\%%F"
echo Exista deja un kit recent descarcat !
goto :Instalare
)
echo Kit-ul complet se descarca in %KitSaga%
set /a "rnd=%RANDOM% %% 3 + 1"
powershell -NoProfile -Command "$url = 'https://mirror%rnd%.sagasoft.ro/programe/%SetupSaga%'; $out = '%KitSaga%'; $bytes = Invoke-WebRequest -Uri $url -UseBasicParsing; [System.IO.File]::WriteAllBytes($out, $bytes.Content); if (Test-Path -LiteralPath $out) { Write-Host 'Descarcare OK!' $out -ForegroundColor Green } else { Write-Host 'Descarcare ESUATA!' -ForegroundColor Red }; Write-Host 'Press any key...'; $null = $Host.UI.RawUI.ReadKey('NoEcho,IncludeKeyDown')"
:Instalare
color 0e & echo Nu inchideti fereastra ! Finalizati instalarea %KitSaga% !
set "CaleInitiala="
for /f "delims=" %%A in ('powershell -NoProfile -Command "(Get-ItemProperty 'HKCU:\SOFTWARE\SAGA' -ErrorAction SilentlyContinue).'%CaleTipInit%'"') do set "CaleInitiala=%%A"
reg add "HKCU\SOFTWARE\SAGA" /v "%CaleTipInit%" /t REG_SZ /d "%CaleSaga%" /f >nul
if exist "%USERPROFILE%\Desktop\%Link%..lnk" REN "%USERPROFILE%\Desktop\%Link%..lnk" "%Link%.lnk"
start /wait "" "%KitSaga%"
if not "%CaleInitiala%"=="" (reg add "HKCU\SOFTWARE\SAGA" /v "%CaleTipInit%" /t REG_SZ /d "%CaleInitiala%" /f >nul)
DEL /F /Q "%CaleSaga%\u.txt" "%CaleSaga%\uu.txt" "%USERPROFILE%\Desktop\%Link%..lnk" >nul 2>&1
powershell -c "Add-Type -AssemblyName Microsoft.VisualBasic;Add-Type -AssemblyName System.Windows.Forms;[Microsoft.VisualBasic.Interaction]::AppActivate('Program Manager');[System.Windows.Forms.SendKeys]::SendWait('{F5}')"
exit
V4.1 - corectii si optimizare

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Mie Sep 09, 2026 9:30 pm
de ciucam544
Cateodata e nevoie de o arhivare rapida a unui folder si poate nu exista inca utilitarul necesar instalat. Am rafinat un mic script pentu autodescarcare si arhivare 7z a folderului curent.
Auto7z_Archive_Current_Folder.cmd

Cod: Selectaţi tot

@echo off
color 3 & setlocal enabledelayedexpansion
title - Auto 7z Archive Current Folder - 2026(c)byGabrieL
set "crdir=%~dp0" & set "dlpath=%crdir%7zr.exe" & set "7ZIP=" & set /a try=0
cd /d "%crdir%" & if exist "C:\Program Files\7-Zip\7z.exe" ( set "7ZIP=C:\Program Files\7-Zip\7z.exe" & goto :archive )
:dl7zr
set /a try+=1
powershell -NoProfile -Command "$url = 'https://7-zip.org/a/7zr.exe'; $out = '%dlpath%'; $bytes = Invoke-WebRequest -Uri $url -UseBasicParsing; [System.IO.File]::WriteAllBytes($out, $bytes.Content)"
if exist %dlpath% ( set "7ZIP=7zr.exe" & goto :archive ) else ( if %try% leq 3 ( color 6 & timeout /t 3 & echo Try %try% & goto :dl7zr ) else ( color 4 & echo 7zr error ... & timeout /t 3 & exit /b ) )
:archive
for /f %%T in ('powershell -NoProfile -Command "Get-Date -Format yyyy.MM.dd_HH.mm.ss"') do set "TIME=%%T"
for %%I in ("%crdir%\.") do set "FOLDER_NAME=%%~nxI"
(echo %~nx0 & echo 7zr.exe & echo excl.txt) > excl.txt
color 3 & cls & "!7ZIP!" a "!FOLDER_NAME!_!TIME!.7z" * [email protected]
del /f /q 7zr.exe excl.txt >nul 2>&1 & timeout /t 3 & exit /b
Se salveaza in folderul care se doreste arhivat si se executa. Scriptul verifica daca exista 7zip instalat in windows (care este si cel mai rapid la arhivare) altfel descarca temporar utilitarul 7zr.exe de pe site-ul oficial 7-zip.org si face arhivarea tot in folderul curent. Deci arhiva trebuie apoi mutata, altfel o veti include in urmatoarea arhivare. Binenteles ca se poate adapta pentru a salva si in alta parte (se adauga o cale la variabila FOLDER_NAME), pentru eventualele automatizari de backup. Cateodata bun pentru a face backup la C:\Temp sau folderele Declaratii sau e-Factura care de cele mai multe ori dureaza foarte de mult si se poate seta sa ruleze si in background.

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Mie Sep 30, 2026 1:31 pm
de ciucam544
Creearea shortcut-urilor SAGA pentru mai multi utilizatori WEB.
Programul Saga desktop memoreaza doar ultimul utilizator care a folosit o baza web. Iata cum se pot construi corect shortcut-uri catre programele saga desktop cu baze in web pentru mai multi utilizatori. Se presupune ca aveti instalate programele saga si gata configurate cu societatile in web. Ca exemplu luam SagaC instalat in E:\SagaC_WEB si SagaPS instalat in F:\SagaPS_WEB. Fiecare dintre aceste instalari are un fisier de configurare config.fdb unde au fost memorate societatile, utilizatorii web si parolele lor. La fel, pentru fiecare utilizator web s-a setat memorarea parolei in windows. Luam ca exemplu utilizatorii [email protected], [email protected] si [email protected]. Fisierele de configurare cu societtile si utilizatorii in web nu trebuie neaparat sa se afle in folderul de instalare al programului saga. Se pot folosii fisierele de redirectionare firebird, configcs.txt. Deci se pot folosii foldere separate cu mai multe colectii de societati sau utilizatori pentru o mai buna organizare. Insa in exemplele care urmeaza am folosit calea de redirectionare firebird identica cu calea de instalare a programului saga. Foarte important, fisierele de acces .RSA pe care utilizatorii le folosesc pentru a accesa bazele web, trebuie sa regaseasca si ele conform configurarii societatilor, de prefereat direct in folderul de instalare saga. Pentru a lansa saga corespunzator, se vor folosii shortcut-uri la consola de windows pentru a modifica parametrii de pornire ai programului saga astfel:

SagaC cu utilizatorul [email protected]

Cod: Selectaţi tot

C:\Windows\System32\cmd /c cd /d "E:\SagaC_WEB"&reg.exe add "HKCU\SOFTWARE\SAGA\SAGALC" /v UserWEB /t REG_SZ /d [email protected] /f&ECHO 127.0.0.1:E:\SagaC_WEB\>configcs.txt&start sc.exe
SagaC cu utilizatorul [email protected]

Cod: Selectaţi tot

C:\Windows\System32\cmd /c cd /d "E:\SagaC_WEB"&reg.exe add "HKCU\SOFTWARE\SAGA\SAGALC" /v UserWEB /t REG_SZ /d [email protected] /f&ECHO 127.0.0.1:E:\SagaC_WEB\>configcs.txt&start sc.exe
SagaC cu utilizatorul [email protected]

Cod: Selectaţi tot

C:\Windows\System32\cmd /c cd /d "E:\SagaC_WEB"&reg.exe add "HKCU\SOFTWARE\SAGA\SAGALC" /v UserWEB /t REG_SZ /d [email protected] /f&ECHO 127.0.0.1:E:\SagaC_WEB\>configcs.txt&start sc.exe
SagaPS cu utilizatorul [email protected]

Cod: Selectaţi tot

C:\Windows\System32\cmd /c cd /d "F:\SagaPS_WEB"&reg.exe add "HKCU\SOFTWARE\SAGA\SAGASPS" /v UserWEB /t REG_SZ /d [email protected] /f&ECHO 127.0.0.1:F:\SagaPS_WEB\>configcs.txt&start sps.exe
SagaPS cu utilizatorul [email protected]

Cod: Selectaţi tot

C:\Windows\System32\cmd /c cd /d "F:\SagaPS_WEB"&reg.exe add "HKCU\SOFTWARE\SAGA\SAGASPS" /v UserWEB /t REG_SZ /d [email protected] /f&ECHO 127.0.0.1:F:\SagaPS_WEB\>configcs.txt&start sps.exe
SagaPS cu utilizatorul [email protected]

Cod: Selectaţi tot

C:\Windows\System32\cmd cd /d "F:\SagaPS_WEB"&reg.exe add "HKCU\SOFTWARE\SAGA\SAGASPS" /v UserWEB /t REG_SZ /d [email protected] /f&ECHO 127.0.0.1:F:\SagaPS_WEB\>configcs.txt&start sps.exe
Aceste shortcut-uri se pot salva pe desktop sau oriunde in alta parte. Se recomanda denumirea simpla si coerenta respectiv SagaCWEB_Client sau SagaPSWEB_Contabil1, eventual si folosirea icoanelor programelor saga.
Atentie ! Linia de comanda a shortcut-ului nu trebuie sa depaseasca 260 de caractere inclusiv spatii, deci se are in vedere folosirea cailor cat mai scurte pentru a prevenii trunchierea comenzii. Daca folositi doar comanda scurta cmd la momentul salvarii shortcut-ului, windowsul va adauga in fata locatia sa, iar daca se depasesc cele 260 de caractre, shortcut-ul va devenii needitabil si trunchiat, generand o eroare. Alta observatie este ca in liniile de comanda expuse, cmd nu are extensie petru a putea posta aici pe forum, altfel tot acest mic ghid ar fi fost blocat, dar odata copiata linia si salvata ca shortcut, windows-ul o repara si adauga si extensia consolei.

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Joi Oct 08, 2026 10:41 am
de ciucam544
SagaWEB Launcher
Pentru ca deja programul saga desktop ramane in urma, si cum incerc sa maresc productivitatea si inlesnirea trecerii de la desktop la web, am facut un script de lansare SagaWEB cu browserul EDGE care arata ca o aplicatie (exact ca si cum am folosii functia F11, dar in fereastra). Este oarceum mai usor de utilizat de cei care nu se descurca direct cu browserul si cu taburile, fiind in fereastra e mai usor de folosit cu drag'n'drop la importuri si probabil si alte avantaje de organizare pe desktop. Scriptul insa nu mai foloseste sesiunea curenta de edge, unde (daca s-a folosit inainte) s-au memorat parolele si cookie-urile de logare. L-am configurat sa foloseasca alt folder cu alt profil, pentru al izola fata de profilul EDGE initial. Asta ajuta si la pastrarea dimensiunii ferestrelor la celelalte profile EDGE deja existente. Dupa deschidere trebuie memorate din nou parolele si utilizatorii si reautorizarea noii sesiuni de lucru pe fiecare utilizator salvat, dupa care se pastreaza in noul profil creeat, pana expira.
SagaWEB.Edge.cmd

Cod: Selectaţi tot

@ECHO OFF
FOR /F "tokens=2*" %%A in ('REG Query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\msedge.exe" /VE 2^>nul') DO SET "MS_EDGE=%%B"
START "" "%MS_EDGE%" --window-size=1450,770 --window-position=50,40 --app=https://web.sagasoft.ro --user-data-dir="%ProgramData%\SagaWEB_EdgeData" -disable-features=msEdgeFreAnimation,msEdgeFreFirstRunExperience,msEdgeFreMarketingPromo,msEdgeTranslate,msUseSpellCheckCorrectionsCard,WinUseBrowserSpellChecker,MicrosoftEditorProofing --no-first-run --no-default-browser-check --no-service-autorun --disable-component-update
Binenteles ca dimensiunea ferestrei si locatia profilului pot fi schimbate dupa necesitati. Daca doriti mai mutle lamuriri si optimizari legat de lucrul cu sagaweb in aceasta forma lasati un mesaj in privat si incerc sa ajut.
Scriptul teoretic functioneaza in noile windows-uri 10 si 11 cu browserul MSEdge gata preinstalat.
PS: SagaWEB.Chrome.cmd (doar daca este instalat in windows)

Cod: Selectaţi tot

@ECHO OFF
FOR /F "tokens=2*" %%A in ('REG Query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\chrome.exe" /VE 2^>nul') DO SET "GGCHROME=%%B"
START "" "%GGCHROME%" --window-size=1450,770 --window-position=50,40 --app=https://web.sagasoft.ro --user-data-dir="%ProgramData%\SagaWEB_ChromeData" --no-first-run --no-default-browser-check --disable-component-update --disable-translate-trigger

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Sâm Oct 10, 2026 7:46 pm
de nicolam76
deja e prea complicat pt un contabil care vrea sa isi faca contabilitatea, nu sa piarda vremea cu configurari si scripturi, programele.. etc...

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Mie Oct 21, 2026 8:41 am
de secaras648
ciucam544 scrie: ↑Mar Sep 01, 2026 5:18 pm ActualizareSagaKitCompletSmart_V4.1.cmd

Cod: Selectaţi tot

@echo off
set cd=%~dp0
set cd=%cd:~0,-1%
net session >nul 2>&1 || (setx SagaCale "%cd%" >nul & powershell -NoProfile -Command "Start-Process -FilePath '%~f0' -Verb RunAs" & exit /b)
title - Actualizare Saga Kit Complet Smart V4.1 - 2026(c)byGabrieL
for /f "delims=" %%C in ('powershell -NoProfile -Command "(Get-Item Env:SagaCale).Value"') do set "CaleSaga=%%C"
if exist "%CaleSaga%\sb.exe" (set "SagaTip=SagaB" & set "SetupSaga=SetupB.exe" & set "CaleTipInit=Lite B 3" & set "Page=saga-b.php" & set "Link=SAGA B.3.0")
if exist "%CaleSaga%\sc.exe" (set "SagaTip=SagaC" & set "SetupSaga=SetupC.exe" & set "CaleTipInit=Lite C 3" & set "Page=saga-c.php" & set "Link=SAGA C.3.0")
if exist "%CaleSaga%\sps.exe" (set "SagaTip=SagaPS" & set "SetupSaga=SetupPS.exe" & set "CaleTipInit=PS 3" & set "Page=saga-ps.php" & set "Link=SAGA PS.3.0")
if "%SagaTip%"=="" (color 0c & echo Nu exista un program saga in folderul curent ! & pause & exit /b)
for /f %%T in ('powershell -NoProfile -Command "Get-Date -Format yyyy.MM.dd_HH.mm.ss"') do set "DATE=%%T"
for /f "usebackq delims=" %%V in (`powershell -NoProfile -Command "$h=Invoke-WebRequest 'https://www.sagasoft.ro/%Page%' -UseBasicParsing; if($h.Content -match 'Versiune:</b>\s*([0-9\.]+)') { $matches[1] }"`) do set "VER=%%V"
color 0a & echo Program Saga detectat: %SagaTip% - Versiune v%VER%.
set "Upd=%CaleSaga%\Actualizari"
if not exist "%Upd%" mkdir "%Upd%"
set "KitSaga=%Upd%\%SagaTip%_%DATE%_v%VER%.exe"
if exist "%Upd%\%SagaTip%_%DATE:~0,13%*_v%VER%.exe" (
for /f "delims=" %%F in ('dir /b /o:-d "%Upd%\%SagaTip%_%DATE:~0,13%*_v%VER%.exe"') do set "KitSaga=%Upd%\%%F"
echo Exista deja un kit recent descarcat !
goto :Instalare
)
echo Kit-ul complet se descarca in %KitSaga%
set /a "rnd=%RANDOM% %% 3 + 1"
powershell -NoProfile -Command "$url = 'https://mirror%rnd%.sagasoft.ro/programe/%SetupSaga%'; $out = '%KitSaga%'; $bytes = Invoke-WebRequest -Uri $url -UseBasicParsing; [System.IO.File]::WriteAllBytes($out, $bytes.Content); if (Test-Path -LiteralPath $out) { Write-Host 'Descarcare OK!' $out -ForegroundColor Green } else { Write-Host 'Descarcare ESUATA!' -ForegroundColor Red }; Write-Host 'Press any key...'; $null = $Host.UI.RawUI.ReadKey('NoEcho,IncludeKeyDown')"
:Instalare
color 0e & echo Nu inchideti fereastra ! Finalizati instalarea %KitSaga% !
set "CaleInitiala="
for /f "delims=" %%A in ('powershell -NoProfile -Command "(Get-ItemProperty 'HKCU:\SOFTWARE\SAGA' -ErrorAction SilentlyContinue).'%CaleTipInit%'"') do set "CaleInitiala=%%A"
reg add "HKCU\SOFTWARE\SAGA" /v "%CaleTipInit%" /t REG_SZ /d "%CaleSaga%" /f >nul
if exist "%USERPROFILE%\Desktop\%Link%..lnk" REN "%USERPROFILE%\Desktop\%Link%..lnk" "%Link%.lnk"
start /wait "" "%KitSaga%"
if not "%CaleInitiala%"=="" (reg add "HKCU\SOFTWARE\SAGA" /v "%CaleTipInit%" /t REG_SZ /d "%CaleInitiala%" /f >nul)
DEL /F /Q "%CaleSaga%\u.txt" "%CaleSaga%\uu.txt" "%USERPROFILE%\Desktop\%Link%..lnk" >nul 2>&1
powershell -c "Add-Type -AssemblyName Microsoft.VisualBasic;Add-Type -AssemblyName System.Windows.Forms;[Microsoft.VisualBasic.Interaction]::AppActivate('Program Manager');[System.Windows.Forms.SendKeys]::SendWait('{F5}')"
exit
V4.1 - corectii si optimizare
1. Cu Run as administrator nu detectează SAGA. Soluția: set "CaleSaga=%cd%" în loc de setx + citirea din Env:SagaCale.
2. Descărcarea e foarte lentă din cauza barei de progres. Soluția: $ProgressPreference='SilentlyContinue' + -OutFile.

Re: Scripturi Ajutatoare - pentru Administratori si Utilizatori Avansati

Scris: Mie Oct 21, 2026 9:01 am
de secaras648
ciucam544 scrie: ↑Mar Feb 03, 2026 8:31 pm Asa cum am postat si aici https://forum.sagasoft.ro/viewtopic.php?p=342548#p342548 mai pun odata scriptul pentru backup compact la folderul saga, backup fara subfolderul cu actualizari si fara subfolderul cu backup-urile de actualizare salv_bd. Acolo am uitat sa mentionez ca se face backup si la setarile din registrii (fisierele .rbk), pentru ca pe fiecare sesiune de windows pot exista configurari diferite, ele putand fi refolosite la nevoie, schimband extensia in .reg si reimportate la loc in windows.

ScriptBackup_FolderSAGA_Compact.cmd

Cod: Selectaţi tot

@echo off
setlocal enabledelayedexpansion
set "CPATH=%~dp0"
set "CPATH=%CPATH:~0,-1%"
net session >nul 2>&1 || (setx SagaCale "%CPATH%" >nul & powershell -NoProfile -Command "Start-Process -FilePath '%~f0' -Verb RunAs" & exit /b)
title - Backup Folder Saga Compact - 2026(c)byGabrieL
for /f "delims=" %%C in ('powershell -NoProfile -Command "(Get-Item Env:SagaCale).Value"') do set "CaleSaga=%%C"
if not defined CaleSaga set "CaleSaga=%CPATH%"
if exist "%CaleSaga%\sb.exe" set "SagaTip=SagaB"
if exist "%CaleSaga%\sc.exe" set "SagaTip=SagaC"
if exist "%CaleSaga%\sps.exe" set "SagaTip=SagaPS"
if "%SagaTip%"=="" (color 0c & echo Nu exista un program saga in folderul curent ! & pause & exit /b)
set "DRIVE=%CaleSaga:~0,2%"
set "DEST=%DRIVE%\Backups_Saga"
for %%G in ("%CaleSaga%") do set "FName=%%~nxG"
if not exist "%DEST%" mkdir "%DEST%"
set "Z7=C:\Program Files\7-Zip\7z.exe"
set "Z7A=%CaleSaga%\7za.exe"
set "ArchEXE=" & set "Arhivator="
if exist "%Z7%" set "ArchEXE=%Z7%" & set "Arhivator=7zip"
if not defined ArchEXE if exist "%Z7A%" set "ArchEXE=%Z7A%" & set "Arhivator=7za_Saga"
if not defined ArchEXE echo Lipseste arhivatorul pentru backup! & pause & exit /b
echo Folosesc arhivator: %Arhivator%
tskill sc /a >nul 2>&1 & tskill sps /a >nul 2>&1 & net stop FirebirdServerFirebird30_Saga >nul 2>&1
for %%S in ("%CaleSaga%") do (
for /f %%i in ('powershell -command "Get-Date -Format \"yyyy-MM-dd_HHmmss\""') do set "DATE=%%i"
del "%%~S\*.rbk" >nul 2>&1
reg export HKCU\SOFTWARE\SAGA "%%~S\sagaset_!DATE!.rbk" /y >nul 2>&1
echo Se face Backup in %DEST%\Bkp!SagaTip!_!FName!_!DATE!.zip
"%ArchEXE%" a -tzip -mx3 "%DEST%\Bkp!SagaTip!_!FName!_!DATE!.zip" "%%~S\*" -x^^!"%%~S\Actualizari" -x^^!"%%~S\salv_bd"
)
net start FirebirdServerFirebird30_Saga >nul 2>&1
echo Backup SAGA finalizat cu succes!
endlocal & pause
Salut! Câteva sugestii la ScriptBackup_FolderSAGA_Compact.cmd:

1. As elimina setx SagaCale + linia for /f ... Env:SagaCale și if not defined, înlocuite cu set "CaleSaga=%CPATH%"
De ce: la „Run as administrator” sau din Task Scheduler, setx nu se execută, CaleSaga primește un spațiu gol, if not defined nu se mai aplică și apare „Nu exista un program saga in folderul curent”. %~dp0 dă oricum folderul corect și după elevare.
Linia de elevare devine:
net session >nul 2>&1 || (powershell -NoProfile -Command "Start-Process -FilePath '%~f0' -Verb RunAs" & exit /b)
2. De adăugat tskill sb /a
De ce: altfel SAGA B nu e închis înainte de backup.
Ora este UTC+03:00 Europe/Bucharest
Pagina 2 din 2

Furnizat de phpBB® Forum Software © phpBB Limited

Translation/Traducere: MX-Publisher CMS